Mam taka zagwozdke i nie wiem jak ją rozwiązać, otóż klikając w mIRCu (616+Invision 3515) na link chciałabym aby otwierał się w Operze (9.52 Bulid 10108), a nie w domyślnej przeglądarce systemu jaką jest IE.
Nie chce tez zmieniać domyślnej przeglądarki systemu, tylko przypisać do mIRCa Opere aby mIRC otwierał w niej linki.
Szukałam w ustawieniach mIRCa i Invision, ale tam nic nie widzałam aby był jakiś przełącznik do tego.
Czy ktoś może mi coś poradzić gdzie moge zmienić przypisanie i czy wogóle da rade tak zrobić jak chce?
http://trout.snt.utwente.nl/ubbthreads/ubbthreads.php?ubb=showflat&Number=2805&page=1&PHPSESSID=af
http://trout.snt.utwente.nl/ubbthreads/ubbthreads.php?ubb=showflat&Board=3&Number=206225&Searchpage=4&Main=38159&Words=link+browser&topic=0&Search=true&PHPSESSID=af#Post205539
Z mIRCem Ci nie pomogę bo dawwwnnoo go już nie używałem. Używam natomiast czasami KVIrca i tam jest to kwestia zmiany scieżki w preferencjach (nowe link otwierane będą poprzez C:\Katalog\Opery\opera.exe %url% zamiast standardowego iexplorer %url%)
Dzieki Barthez za wskazówke gdzie szukać. Pomógł ten skrypt do mIRCa, mozna po zaladowaniu go przypisać do mIRCa jaką sie chce przeglądarke. Oczywiście zainstalowana w systemie. 
on ^*:hotlink:*//*.*:*:{ }
on *:hotlink:*//*.*:*: http $1
on ^*:hotlink:*www.*:*:{ }
on *:hotlink:*www.*:*: http $1
alias http {
var %site = $remove($1,',",>,<)
var %trailing = ,&.&!&?
.comopen wsh WScript.Shell
.comclose wsh $com(wsh, Run, 1, *bstr, %_Browser $iif($istok(%trailing,$right(%site,1),38),$left(%site,-1),%site), i1, 3)
}
alias -l InternetExplorer if (%IEXPLORE.EXE) return $iif(%_Browser == %IEXPLORE.EXE,$style(1)) Internet Explorer
alias -l Mozilla if (%mozilla.exe) return $iif(%_Browser == %mozilla.exe,$style(1)) Mozilla
alias -l Netscape if (%netscape.exe) return $iif(%_Browser == %netscape.exe,$style(1)) Netscape
alias -l Opera if (%Opera.exe) return $iif(%_Browser == %Opera.exe,$style(1)) Opera
alias -l Phoenix if (%phoenix.exe) return $iif(%_Browser == %phoenix.exe,$style(1)) Phoenix
alias -l FireFox if (%FireFox.exe) return $iif(%_Browser == %FireFox.exe,$style(1)) FireFox
alias -l Other {
if ((!$istok(%_Browsers,$nopath($remove(%_Browser,")),158)) && ($len(%_Browser))) return $+($style(1),Other)
return Other
}
menu * {
-
SetBrowser
.$InternetExplorer: set %_Browser %IEXPLORE.EXE
.$FireFox: set %_Browser %FireFox.exe
.$Mozilla: set %_Browser %mozilla.exe
.$Netscape: set %_Browser %netscape.exe
.$Opera: set %_Browser %Opera.exe
.$Phoenix: set %_Browser %phoenix.exe
.$Other: set %_Browser $+(",$$sfile("C:\Program Files\*.exe",Pick a completely different browser,Select),")
.-
.Unload: .unload -rs $script
}
on *:UNLOAD: unset %_Browser* %IEXPLORE.EXE %mozilla.exe %netscape.exe %Opera.exe %phoenix.exe
on *:LOAD: set %_browsers IEXPLORE.EXEžmozilla.exežnetscape.exežOpera.exežphoenix.exe | _find.browser 1
alias _find.browser {
var %b
if ($1 == 1) %b = $findfile(C:\,IEXPLORE.EXE,0,set %IEXPLORE.EXE $+(",$1-,"))
elseif ($1 == 2) %b = $findfile(C:\,FireFox.exe,1,set %FireFox.exe $+(",$1-,"))
elseif ($1 == 3) %b = $findfile(C:\,mozilla.exe,1,set %mozilla.exe $+(",$1-,"))
elseif ($1 == 4) %b = $findfile(C:\,netscape.exe,1,set %netscape.exe $+(",$1-,"))
elseif ($1 == 5) %b = $findfile(C:\,Opera.exe,1,set %Opera.exe $+(",$1-,"))
elseif ($1 == 6) {
%b = $findfile(C:\,phoenix.exe,1,set %phoenix.exe $+(",$1-,"))
linesep -a
echo $color(info) -ati2 * BrowserSwitch initiliazed
echo $color(info) -ati2 *
echo $color(info) -ati2 * Right-click in any window
echo $color(info) -ati2 * Select Set Browser and choose your browser
echo $color(info) -ati2 *
echo $color(info) -ati2 * Double-clicking a link will run it
echo $color(info) -ati2 * /http www.mirc.com will also run the link in your selected browser
linesep -a
set %_Browser %IEXPLORE.EXE
halt
}
.timer 1 2 _find.browser $calc($1 + 1)
}